zOs/REXX.O13/PVSRRMEM

/* rexx ****************************************************************
    pvsrRmEm: remove empty datasets
                                                  kpco 4, pvs
         arguments: a list of dd names (space separated)
         function:  for each ddName from arguments
                        if a dd with this name is preallocated
                            if this file is empty then delete it
***********************************************************************/
parse arg args
say 'pvsrRmEm begin' args

do i=1 to words(args)
    dd = word(args, i)
    ld = listDsi(dd 'file')
    if ld <> 0 then
        say 'rc' ld 'from listDsi('dd 'file):' sysMsgLvl2
    else do
        say 'dd' dd 'dsn' sysDsName ,
                    'used' sysUsed', alloc' sysAlloc sysUnits
        if sysUsed = 0 then do
            say 'deleting dd' dd 'dsn' sysDsName
            address tso "delete '"sysDsName"'"
            if rc <> 0 then
                say "error rc" rc "in delete '"sysDsName"'"
            end
        end
    end

say 'pvsrRmEm end' args
exit